條條道路通羅馬。其實在Excel中，同一個問題也有很多種解決方法，比如條件求和。SUMIFS和SUMPRODUCT都能實現(xiàn)，區(qū)別在哪，哪個更好用？

將SUMPRODUCT函數(shù)的語法變形，求和區(qū)域移動到最前面。兩者的語法超級像。

=SUMIFS(求和區(qū)域,條件區(qū)域1,條件1,條件區(qū)域2,條件2)

=SUMPRODUCT(求和區(qū)域*(條件區(qū)域1=條件1)*(條件區(qū)域2=條件2))

下面通過具體案例進行詳細說明兩者的區(qū)別。

1、根據(jù)左邊的明細，統(tǒng)計部門的總金額

一般情況下，SUMIFS支持直接引用整列，而SUMPRODUCT只能引用有內(nèi)容的區(qū)域，因此前者的公式看起來更加簡潔。

=SUMIFS(E:E,B:B,G2)

=SUMPRODUCT($E$2:$E$12*($B$2:$B$12=G2))

特殊情況下，SUMPRODUCT也支持引用整列，不過不建議使用，太卡了。

2、根據(jù)左邊的明細，按部門、姓名統(tǒng)計總金額

條件越多，SUMIFS的簡潔越能體現(xiàn)。

=SUMIFS(E:E,B:B,G2,C:C,H2)

=SUMPRODUCT($E$2:$E$12*($B$2:$B$12=G2)*($C$2:$C$12=H2))

3、根據(jù)左邊的明細，按部門、姓氏統(tǒng)計總金額

姓氏就是每個姓名的首個字。

SUMIFS支持使用通配符，H2&'*'就代表首字符。SUMPRODUCT不支持通配符，只能用LEFT從左邊提取字符。

=SUMIFS(E:E,B:B,G2,C:C,H2&'*')

=SUMPRODUCT($E$2:$E$12*($B$2:$B$12=G2)*(LEFT($C$2:$C$12,1)=H2))

4、根據(jù)左邊的明細，按部門、姓名簡稱統(tǒng)計總金額

經(jīng)?？梢杂龅胶喎Q和全稱的查找，有的人為了貪圖方便，記錄內(nèi)容都用簡稱。

SUMPRODUCT不支持通配符的弊端在這里進一步體現(xiàn)，需要借助FIND判斷姓名簡稱有沒出現(xiàn)，F(xiàn)IND的結(jié)果還會出現(xiàn)錯誤值，還需要借助ISNUMBER判斷內(nèi)容是不是數(shù)字，很麻煩。

=SUMIFS(E:E,B:B,G2,C:C,'*'&H2&'*')

=SUMPRODUCT($E$2:$E$12*($B$2:$B$12=G2)*ISNUMBER(FIND(H2,$C$2:$C$12)))

5、根據(jù)左邊的明細，統(tǒng)計每月的總金額

SUMIFS的條件區(qū)域不支持嵌套MONTH，只能通過輔助列解決。

=MONTH(A2)

再根據(jù)輔助列進行條件求和。

=SUMIFS(E:E,F:F,G2)

而SUMPRODUCT每個參數(shù)都支持嵌套其他函數(shù)，因此不需要輔助列，這是優(yōu)勢。

=SUMPRODUCT($E$2:$E$12*(MONTH($A$2:$A$12)=G2))

6、根據(jù)左邊的二維明細表，統(tǒng)計部門的總金額

SUMIFS不支持統(tǒng)計二維明細表，需要用輔助列對所有列先求和。

=SUM(B2:K2)

再根據(jù)輔助列進行條件求和。

=SUMIFS(L:L,A:A,M2)

而SUMPRODUCT不需要輔助列，這是優(yōu)勢。

=SUMPRODUCT($B$2:$K$12*($A$2:$A$12=M2))

總結(jié)：在盧子眼中，如果只是常規(guī)的條件求和，SUMIFS簡直就是無敵的存在。如果區(qū)域需要嵌套其他函數(shù)，以及二維數(shù)據(jù)源條件求和，SUMPRODUCT會更有優(yōu)勢。