ORACLE Procedure 存儲(chǔ)過(guò)程語(yǔ)法

昵稱10504424 2013-06-07

展開全文

子程序和程序包
總結(jié)：
子程序是命名的PL/SQL塊，可帶參數(shù)并可在需要時(shí)隨時(shí)調(diào)用。
PL/SQL有兩種類型的子程序，即過(guò)程和函數(shù)。
過(guò)程用于執(zhí)行特定的任務(wù)，函數(shù)用于執(zhí)行任務(wù)并返回值。
程序包是對(duì)相關(guān)類型、變量、常量、游標(biāo)、異常、過(guò)程和函數(shù)的封裝。
程序包由包規(guī)范和包主體兩部分組成。
包規(guī)范是包的接口，包含公用對(duì)象及其類型。
包主體實(shí)現(xiàn)包規(guī)范中的游標(biāo)和子程序，包主體中的聲明僅限于在包內(nèi)使用。
程序包中游標(biāo)的定義分為游標(biāo)規(guī)范和游標(biāo)主體兩部分。

語(yǔ)法及示例：
1、存儲(chǔ)過(guò)程
創(chuàng)建存儲(chǔ)過(guò)程的語(yǔ)法：
CREATE [OR REPLACE] PROCEDURE procedure_name
[(parameter_list)]
{IS|AS}
[local_declarations]
BEGIN
executable_statements
[EXCEPTION
exception_handlers]
END [procedure_name];
其中：procedure_name是過(guò)程的名稱。
parameter_list是參數(shù)列表。
local_declarations是局部聲明。
executable_statements是可執(zhí)行語(yǔ)句。
exception_handlers是異常處理程序。
示例1：演示創(chuàng)建過(guò)程(參數(shù)列表中為IN參數(shù)賦予一個(gè)默認(rèn)值，不能為OUT、IN OUT參數(shù)賦予默認(rèn)值)
create or replace procedure find_emp(emp_no in number:=7900)
as
empname varchar2(20);
begin
select ename into empname from emp where empno=emp_no;
dbms_output.put_line('雇員姓名是 '||empname);
exception
when no_data_found then
dbms_output.put_line('雇員編號(hào)未找到');
end find_emp;

調(diào)用過(guò)程：EXECUTE procudure_name(parameters_list);
也可以在過(guò)程里面調(diào)用，直接寫上procudure_name而不必寫EXECUTE。

示例2：演示創(chuàng)建帶OUT參數(shù)的過(guò)程
create or replace procedure test(value1 varchar2,value2 out number)
is
identity number;
begin
select sal into identity from emp where empno=value1;
if identity<2000 then
value2:=1000;
else
value2:=500;
end if;
end;

調(diào)用帶OUT參數(shù)的過(guò)程：
declare
value2 number;
begin
test('7900',value2);
dbms_output.put_line(value2);
end;

示例3：演示創(chuàng)建帶IN OUT參數(shù)的過(guò)程
create or replace procedure swap(p1 in out number,p2 in out number)
is
v_temp number;
begin
v_temp:=p1;
p1:=p2;
p2:=v_temp;
end;

調(diào)用帶IN OUT參數(shù)的過(guò)程：
declare
num1 number:=100;
num2 number:=200;
begin
swap(num1,num2);
dbms_output.put_line('num1= '||num1);
dbms_output.put_line('num2= '||num2);
end;

示例4：將過(guò)程的執(zhí)行權(quán)限授予其他用戶
GRANT EXECUTE ON find_emp TO scott;
GRANT EXECUTE ON swap TO PUBLIC;
將find_emp過(guò)程的執(zhí)行權(quán)限授予給用戶scott，將執(zhí)行swap過(guò)程的權(quán)限授予所有數(shù)據(jù)庫(kù)用戶。

刪除過(guò)程語(yǔ)法：DROP PROCEDURE procudure_name;

2、函數(shù)
定義函數(shù)的語(yǔ)法如下：
CREATE [OR REPLACE] FUNCTION function_name
[(parameter_list)]
RETURN datatype
{IS|AS}
[local_declarations]
BEGIN
executable_statements
[EXCEPTION
exception_handlers]
END [function_name];
其中：function_name是函數(shù)的名稱。
parameter_list是參數(shù)列表。
local_declarations是局部聲明。
executable_statements是可執(zhí)行語(yǔ)句。
exception_handlers是異常處理程序。
使用函數(shù)時(shí)注意：形式參數(shù)必須只使用數(shù)據(jù)庫(kù)類型，不得使用PL/SQL類型。函數(shù)的返回類型也必須是數(shù)據(jù)庫(kù)類型。
函數(shù)不能單獨(dú)執(zhí)行，只能通過(guò)SQL語(yǔ)句或PL/SQL程序塊來(lái)調(diào)用。
示例5：演示如何創(chuàng)建函數(shù)
create or replace function fun_hello
return varchar2 is
begin
return '朋友，您好';
end;
調(diào)用函數(shù)：select fun_hello from dual;

函數(shù)的授權(quán)：同過(guò)和的授權(quán)一樣具體請(qǐng)看示例4。
刪除函數(shù)：DROP FUNCTION function_name

過(guò)程和函數(shù)的差異
過(guò)程函數(shù)
作為PL/SQL語(yǔ)句執(zhí)行作為表達(dá)式的一部分調(diào)用
在規(guī)范中不包含RETURN子句必須在規(guī)范中包含RETURN子句
不返回任何值必須返回單個(gè)值
可以包含RETURN語(yǔ)句，但是與函數(shù)不同，它不能用于返回值必須包含至少一條RETURN語(yǔ)句

3、程序包
創(chuàng)建包規(guī)范的語(yǔ)法：
CREATE [OR REPLACE] PACKAGE package_name
IS|AS
[Public type and item declarations]
[Subprogram specifications]
END [package_name];
其中：package_name是包的名稱。
Public type and item declarations是聲明類型、常量、變量、異常和游標(biāo)等。
Subprogram specifications聲明PL/SQL子程序。

示例6：演示創(chuàng)建程序包規(guī)范
create or replace package pack_op is
procedure pro_print_ename(id number);
procedure pro_print_sal(id number);
function fun_re_date(id number) return date;
end;

創(chuàng)建包主體的語(yǔ)法：
CREATE [OR REPLACE] PACKAGE BODY package_name
IS|AS
[Public type and item declarations]
[Subprogram bodies]
[BEGIN
Initialization_statements]
END [package_name];
其中：package_name是包的名稱。
Public type and item declarations是聲明類型、常量、變量、異常和游標(biāo)等。
Subprogram bodies是定義公共和私有PL/SQL子程序。

示例7：演示創(chuàng)建程序包主體
create or replace package body pack_op is
procedure pro_print_ename(id number) is
name emp.ename%type;
begin
select ename into name from emp where empno=id;
dbms_output.put_line('職員姓名：'||name);
end pro_print_ename;
procedure pro_print_sal(id number) is
salary emp.sal%type;
begin
select sal into salary from emp where empno=id;
dbms_output.put_line('職員工資：'||salary);
end pro_print_sal;
function fun_re_date(id number) return date is
bedate emp.hiredate%type;
begin
select hiredate into bedate from emp where empno=id;
return bedate;
end fun_re_date;
end pack_op;

示例8：調(diào)用程序包中創(chuàng)建的過(guò)程和函數(shù)
exec pack_op.pro_print_ename(7900);
exec pack_op.pro_print_sal(7900);
select pack_op.fun_re_date(7900) from dual;

示例9：演示程序包中的游標(biāo)
創(chuàng)建包規(guī)范
create or replace package pack_emp is
cursor cur_emp return emp%rowtype;
procedure pro_cur;
end pack_emp;

創(chuàng)建包主體
create or replace package body pack_emp is
cursor cur_emp return emp%rowtype is
select * from emp;
procedure pro_cur is
rec_emp emp%rowtype;
begin
open cur_emp;
loop
fetch cur_emp into rec_emp;
exit when cur_emp%notfound;
if rec_emp.sal<1000 then
dbms_output.put_line('員工工資：'||rec_emp.sal||'，需加倍努力爭(zhēng)取提高工資');
elsif rec_emp.sal>=1000 and rec_emp.sal<2000 then
dbms_output.put_line('員工工資：'||rec_emp.sal||'，工資一般，爭(zhēng)取搞個(gè)部門經(jīng)理做做');
else
dbms_output.put_line('員工工資：'||rec_emp.sal||'，工資不錯(cuò)，爭(zhēng)取搞個(gè)總經(jīng)理做做');
end if;
end loop;
end pro_cur;
end pack_emp;

調(diào)用程序包中的過(guò)程以調(diào)用程序包中的游標(biāo)
exec pack_emp.pro_cur;

示例10：存儲(chǔ)過(guò)程返回游標(biāo)的子程序包(此程序包返回r_cur游標(biāo))
CREATE OR REPLACE package SCOTT.pk_wt
is
type mytype is ref cursor;
procedure p_wt(mycs out mytype);
end;

CREATE OR REPLACE package BODY SCOTT.pk_wt
is
procedure p_wt(mycs out mytype)
is
r_cur mytype;
begin
open r_cur for select * from emp;
mycs:=r_cur;
end p_wt;
end pk_wt;

查詢有關(guān)過(guò)程、函數(shù)和程序包的信息：USER_OBJECTS數(shù)據(jù)字典視圖
column object_name format a18
select object_name,object_type from user_objects where object_type in ('PROCEDURE','FUNCTION','PACKAGE','PACKAGE BODY');

注意事項(xiàng)：

1，存儲(chǔ)過(guò)程參數(shù)不帶取值范圍，in表示傳入(只能位于等號(hào)右邊)，out表示輸出(只能位于等號(hào)左邊),in out表示該類型既能被賦值也能傳值;

類型可以使用任意Oracle中的合法類型。

2，變量帶取值范圍，后面接分號(hào)

3，在判斷語(yǔ)句前最好先用count（*）函數(shù)判斷是否存在該條操作記錄

4，用select 。。。into。。。給變量賦值

5，在代碼中拋異常用 raise+異常名

6，用select時(shí)，后面必須接into字段，在游標(biāo)和循環(huán)里面就另當(dāng)別論了

7，在package里，不能create or replace

8，不寫in，out，默認(rèn)為in

本站是提供個(gè)人知識(shí)管理的網(wǎng)絡(luò)存儲(chǔ)空間，所有內(nèi)容均由用戶發(fā)布，不代表本站觀點(diǎn)。請(qǐng)注意甄別內(nèi)容中的聯(lián)系方式、誘導(dǎo)購(gòu)買等信息，謹(jǐn)防詐騙。如發(fā)現(xiàn)有害或侵權(quán)內(nèi)容，請(qǐng)點(diǎn)擊一鍵舉報(bào)。

轉(zhuǎn)藏 分享

QQ空間 QQ好友新浪微博微信

獻(xiàn)花（0） +1

來(lái)自：昵稱10504424 > 《Oracle》

舉報(bào)/認(rèn)領(lǐng)