我學(xué)公式指標(biāo)、寫公式指標(biāo)
能夠看懂和運(yùn)用公式指標(biāo)，是做股票的基本功。
中國人的傳統(tǒng)，是《易經(jīng)》，易經(jīng)就是簡單容易之道，中國人的天性就是追求簡單容易，不簡單、不容易，就要重新選擇。
中醫(yī)的辦法，就是透過現(xiàn)象看本質(zhì)。我們不需要開膛破肚去研究一個(gè)人的內(nèi)部結(jié)構(gòu)，只要通過觀察現(xiàn)象，比類取象，就能夠知道看不見的東西的變化，就能夠知道自己沒法分解研究的東西的變化。
所以我做所有的事，都是觀察、調(diào)試，再觀察，再調(diào)試，直到滿意。
這是中國人研究問題的最簡便方法。
我研究股票指標(biāo)、公式，也是這樣。
☆ ☆ ☆
我看到《資金流向》好用，但不知道它的數(shù)值的涵義，我就把它下載下來： |
{資金流向}
ZC_1:=IF(L<DYNAINFO(7),0,IF(H>DYNAINFO(7),DYNAINFO(7)-(DYNAINFO(7)-H+0.02)/(H-L+0.02),0));
ZC_2:=DMA(ZC_1,V/CAPITAL)*100;
出貨:=IF(ZC_2>0 AND ZC_2>REF(ZC_2,1),ZC_2/20,0);
PJJ:=DMA((H+L+C*2)/4,0.9);
JJ:=REF(EMA(PJJ,3),1);
QJJ:=VOL/((H-L)*2-ABS(C-O));
XVL:=IF(C>O,QJJ*(H-L),IF(C<O,QJJ*(H-O+(C-L)),VOL/2))+IF(C>O,0-QJJ*(H-C+(O-L)),IF(C<O,0-QJJ*(H-L),0-VOL/2));
ZLL:=VOL/CAPITAL;
HSL1:=IF(ZLL>10,10,ZLL);
HSL:=XVL/1000/1.15;
攻擊流量:=HSL*0.55+REF(HSL,1)*0.33+REF(HSL,2)*0.22;
GJJ:=EMA(攻擊流量,8);
LLJX:=EMA(攻擊流量,3);
流量:LLJX,COLORC875B7,COLORRED,NODRAW;
STICKLINE(流量>0,流量,0,2.3,0),COLORRED;
STICKLINE(流量<0,流量,0,2.3,0),COLORFF4242;
流量基線:GJJ,COLOR00BBBB,COLORGREEN;
STICKLINE(HSL*0.4>=0,HSL*0.4*1.5,0,0,1),COLORYELLOW;
STICKLINE(HSL*0.4<0,HSL*0.4*1.5,0,0,1),COLORGREEN;
ZJLL:=REF(LLJX,1);
QZJJ:=(((LLJX-ZJLL)/ZJLL)*100);
流量幅%:IF(((LLJX>0) AND (ZJLL<0)),ABS(QZJJ),IF((((LLJX<0) AND (ZJLL<0)) AND (LLJX<ZJLL)),(0-QZJJ),QZJJ))COLORMAGENTA,NODRAW;
力度:HSL/1000,COLOR9B37FF,COLORRED,NODRAW;
周流量:SUM(LLJX,5),COLORFFBFDF,COLORMAGENTA,NODRAW;
BB:=REF(周流量,1);
ZQZJJ:=(周流量-BB)/BB*100;
周幅%:IF(周流量>0 AND BB<0,ABS(ZQZJJ),IF(周流量<0 AND BB<0 AND 周流量<BB,-ZQZJJ,ZQZJJ))COLORMAGENTA,NODRAW;
VARQ1:=REF((LOW+OPEN+CLOSE+HIGH)/4,1);
VARQ2:=SMA(ABS(LOW-VARQ1),13,1)/SMA(MAX(LOW-VARQ1,0),10,1);
VARQ3:=EMA(VARQ2,10);
VARQ4:=LLV(LOW,33);
VARQ5:=EMA(IF(LOW<=VARQ4,VARQ3,0),3);
主力進(jìn)場:STICKLINE(VARQ5>REF(VARQ5,1) AND 出貨<=0,0,VARQ5,1,0),COLORWHITE;
☆ ☆ ☆
然后我就一點(diǎn)點(diǎn)研究它。
我知道DYNAINFO(7)的意思是現(xiàn)價(jià)。但不知道DYNAINFO(7)的涵義是什么。所以我就寫一行代碼：
現(xiàn)價(jià):DYNAINFO(7);
電腦執(zhí)行后，發(fā)現(xiàn)是貫通左右的當(dāng)前股價(jià)的一條線。
接著，我同年我剛寫的現(xiàn)價(jià)那一行，去掉原程序第一行冒號后的等號，輸入到電腦：
ZC_1:IF(LDYNAINFO(7),DYNAINFO(7)-(DYNAINFO(7)-H+0.02)/(H-L+0.02),0));
H為最高價(jià)，L為最低價(jià)。電腦執(zhí)行后，發(fā)現(xiàn)比現(xiàn)價(jià)高的股價(jià)就畫到現(xiàn)價(jià)之上指定位置，否則歸零。再恢復(fù)第一行的等號，不再顯示它，用同樣的方法，去掉等號，處理下一行。
ZC_2:DMA(ZC_1,V/CAPITAL)*100;
V為成交量(手)；CAPITAL為當(dāng)前流通股本(手)；DMA為動(dòng)態(tài)移動(dòng)平均。電腦執(zhí)行后，發(fā)現(xiàn)它是把ZC_1線改成曲線，數(shù)值放大100倍。用同樣的方法（即將剛顯示過的那一行，在冒號后加上等號，不顯示它），再寫下一行：
出貨:IF(ZC_2>0 AND ZC_2>REF(ZC_2,1),ZC_2/20,0);
這行的涵義是：如果ZC_2>0ANDZC_2>昨日ZC_2,返回ZC_2/20,否則返回0。電腦執(zhí)行后，發(fā)現(xiàn)它是：如果ZC_2上漲，則取ZC_2的20分一之值，否則歸零。
然后就這樣，一行行往電腦里寫，一行行看，它是什么意思。輸入進(jìn)去的原指標(biāo)的語句不能刪，只能在冒號后加上等號，不顯示它！能夠刪除的，是自己為了了解字符串涵義而寫上的語句。這樣，我就明白了：
PJJ:DMA((H+L+C*2)/4,0.9); 平均價(jià)的九成，畫均線。
JJ:REF(EMA(PJJ,3),1); 三天前的九成平均均線。
把VOL和QJJ同時(shí)展示：
量:VOL,COLORRED;
QJJ:VOL/((H-L)*2-ABS(C-O));
ABS是取絕對值；C是收盤價(jià)；O 是開盤價(jià)。QJJ取VOL之均價(jià)平緩值，價(jià)高時(shí)減少了VOL，而價(jià)低時(shí)增加了VOL。
XVL:IF(C>O,QJJ*(H-L),IF(C<O,QJJ*(H-O+(C-L)),VOL/2))+IF(C>O,0-QJJ*(H-C+(O-L)),IF(C<O,0-QJJ*(H-L),0-VOL/2)); XVL的絕對值通常是VOL的1/2左右。股價(jià)收陰，則XVL為負(fù)。
ZLL:VOL/CAPITAL; 以小數(shù)點(diǎn)表示的換手率
HSL1:=IF(ZLL>10,10,ZLL); 換手率不大于10
HSL:=XVL/1000/1.15; XVL/1000/1.15,即是 XVL/1150， 取XVL的1150分之一。
攻擊流量:=HSL*0.55+REF(HSL,1)*0.33+REF(HSL,2)*0.22; 0.55的當(dāng)天縮小成交量+0.33的縮小昨日+0.22前天縮小成交量。繼續(xù)往下寫三行：
GJJ:=EMA(攻擊流量,8);
LLJX:=EMA(攻擊流量,3);
流量:LLJX,COLORC875B7,COLORRED,NODRAW;
流量就是LLJX，以下的程序代碼中，“LLJX”全部改成“流量”。COLORC875B7 和 COLORRED 兩種顏色重復(fù)，只取一種。以下的代碼中，還有多次這種情況，一律只要用英文直白說出顏色的那個(gè)代碼。NODRAW表示不顯示圖象，但保留顯示數(shù)字。上兩行合并成：
流量:=EMA(攻擊流量,3),COLORRED,NODRAW;
STICKLINE是畫色柱，
STICKLINE(流量>0,流量,0,2.3,0),COLORRED;
STICKLINE(流量<0,流量,0,2.3,0),COLORFF4242;
色柱的意義很明白：
當(dāng)滿足條件流量>0時(shí),在流量和0位置之間畫柱狀線,寬度為2.3,0不為0則畫空心柱.,畫紅色
當(dāng)滿足條件流量<0時(shí),在流量和0位置之間畫柱狀線,寬度為2.3,0不為0則畫空心柱.,COLORFF4242
為了節(jié)省篇幅，不一一解釋了，如果需要，只在行后做一點(diǎn)說明。代碼用藍(lán)色，說明用黑色。
流量基線:GJJ,COLOR00BBBB,COLORGREEN; COLOR00BBBB 是多余的，可以刪掉。
STICKLINE(HSL*0.4>=0,HSL*0.4*1.5,0,0,1),COLORYELLOW; 細(xì)柱線，黃色。
STICKLINE(HSL*0.4<0,HSL*0.4*1.5,0,0,1),COLORGREEN; 細(xì)柱線，綠色。
ZJLL:=REF(,1); 前一日的流量。
QZJJ:=(((流量-ZJLL)/ZJLL)*100); 數(shù)學(xué)算式的涵義很清楚，不解釋。
流量幅%:IF(((流量>0) AND (ZJLL<0)),ABS(QZJJ),IF((((流量<0) AND (ZJLL<0)) AND (流量<ZJLL)),(0-QZJJ),QZJJ))COLORMAGENTA,NODRAW; 流量幅%的數(shù)值是：如果滿足((流量>0)和(ZJLL<0)二個(gè)條件)，返回QZJJ的絕對值，否則[如果滿足(((流量<0)和(ZJLL<0))和(流量<ZJLL)三個(gè)條件)，返回(0-QZJJ)]，否則返回QZJJ，畫洋紅色，只顯示數(shù)字，不畫圖。原代碼COLORMAGENTA前，應(yīng)加“,”號。
力度:HSL/1000,COLOR9B37FF,COLORRED,NODRAW; 縮小1000倍。COLOR9B37FF, 是多余的，可以刪掉。
周流量:SUM(流量,5),COLORFFBFDF,COLORMAGENTA,NODRAW; 五日流量。COLORFFBFDF, 是多余的，可以刪掉。
BB:=REF(周流量,1); 前一日流量。
ZQZJJ:=(周流量-BB)/BB*100; 數(shù)學(xué)算式的涵義很清楚，不解釋。
周幅%:IF(周流量>0 AND BB<0,ABS(ZQZJJ),IF(周流量<0 AND BB<0 AND 周流量<BB,-ZQZJJ,ZQZJJ))COLORMAGENTA,NODRAW; 流量幅%的數(shù)值是：周幅%:如果周流量>0和BB<0,返回ZQZJJ的絕對值,否則返回如果周流量<0和BB<0AND周流量<BB,返回-ZQZJJ,否則返回ZQZJJ，畫洋紅色，只顯示數(shù)字，不畫圖。原代碼COLORMAGENTA前，應(yīng)加“,”號。
以下是底警示，提示建倉位置
VARQ1:=REF((LOW+OPEN+CLOSE+HIGH)/4,1); 前一日平均價(jià)。
VARQ2:=SMA(ABS(LOW-VARQ1),13,1)/SMA(MAX(LOW-VARQ1,0),10,1); 和K線是反向的。10日可能是數(shù)值很小的小數(shù)，由于已將實(shí)際成交量縮小了1000倍，所以改成15日比較諧調(diào)。
VARQ3:=EMA(VARQ2,10); 和K線是反向的。
VARQ4:=LLV(LOW,33); 33日內(nèi)的最低價(jià)。
{VARQ5:=EMA(IF(LOW<=VARQ4,VARQ3,0),3);} 這是原代碼。由于有時(shí)數(shù)值會非常大，我把它改成下行。為仍能保留在公式中，我加了大引號“{}”
VARQ5:=EMA(IF(LOW<=VARQ4 AND VARQ3<=250,VARQ3/2,IF(VARQ3>250,VARQ3/10,0)),3);
主力進(jìn)場:STICKLINE(VARQ5>REF(VARQ5,1) AND 出貨<=0,0,VARQ5,1,0),COLORWHITE; 畫白色柱線。
☆ ☆ ☆
如果我們再加上“持股成本”和“流通億股”，再調(diào)整一下顏色，可以把《資金流向》寫成：
{資金流向}
成本:DMA(AMOUNT/V/100,V/CAPITAL),NODRAW,COLOREEFFCC;
ZC_1:=IF(L<DYNAINFO(7),0,IF(H>DYNAINFO(7),DYNAINFO(7)-(DYNAINFO(7)-H+0.02)/(H-L+0.02),0));
ZC_2:=DMA(ZC_1,V/CAPITAL)*100;
出貨:=IF(ZC_2>0 AND ZC_2>REF(ZC_2,1),ZC_2/20,0);
PJJ:=DMA((H+L+C*2)/4,0.9);
JJ:=REF(EMA(PJJ,3),1);
量:=VOL,COLORRED;
QJJ:=VOL/((H-L)*2-ABS(C-O));
XVL:=IF(C>O,QJJ*(H-L),IF(C<O,QJJ*(H-O+(C-L)),VOL/2))+IF(C>O,0-QJJ*(H-C+(O-L)),IF(C<O,0-QJJ*(H-L),0-VOL/2));
ZLL:=VOL/CAPITAL;
HSL1:=IF(ZLL>10,10,ZLL);
HSL:=XVL/1150;
攻擊流量:=HSL*0.55+REF(HSL,1)*0.33+REF(HSL,2)*0.22;
GJJ:=EMA(攻擊流量,8),COLORRED;
流量:EMA(攻擊流量,3),COLORRED,NODRAW;
STICKLINE(流量>0,流量,0,2.3,0),COLORRED;
STICKLINE(流量<0,流量,0,2.3,0),COLORFF4242;
流量基線:GJJ,COLORGREEN;
STICKLINE(HSL>=0,HSL*0.6,0,0,1),COLORYELLOW;
STICKLINE(HSL<0,HSL*0.6,0,0,1),COLORGREEN;
ZJLL:=REF(流量,1);
QZJJ:=(((流量-ZJLL)/ZJLL)*100);
流量幅%:IF(((流量>0) AND (ZJLL<0)),ABS(QZJJ),IF((((流量<0) AND (ZJLL<0)) AND (流量<ZJLL)),(0-QZJJ),QZJJ)),COLORMAGENTA,NODRAW;
力度:=HSL/1000,COLORRED,NODRAW;
周流量:SUM(流量,5),COLORYELLOW,NODRAW;
BB:=REF(周流量,1);
ZQZJJ:=(周流量-BB)/BB*100;
周幅%:IF(周流量>0 AND BB<0,ABS(ZQZJJ),IF(周流量<0 AND BB<0 AND 周流量<BB,-ZQZJJ,ZQZJJ)),COLORWHITE,NODRAW;
VARQ1:=REF((LOW+OPEN+CLOSE+HIGH)/4,1);
VARQ2:=SMA(ABS(LOW-VARQ1),13,1)/SMA(MAX(LOW-VARQ1,0),15,1);
VARQ3:=EMA(VARQ2,10);
VARQ4:=LLV(LOW,33);
VARQ5:=EMA(IF(LOW<=VARQ4 AND VARQ3<=250,VARQ3/2,IF(VARQ3>250,VARQ3/10,0)),3);
主力進(jìn)場:STICKLINE(VARQ5>REF(VARQ5,1) AND 出貨<=0,0,VARQ5,1,0),COLORWHITE;
流通億股:FINANCE(7)/100000000,NODRAW,COLOREEFFCC;
☆ ☆ ☆
現(xiàn)在，《資金流向》在電腦里執(zhí)行，就是這樣。
和最大交易量配合，它更好用。
特別是適用于像白云山A這樣的股票。白云山A昨天開盤拉漲停板，然后跌下來。今天低開高走，但沒有補(bǔ)昨天的缺口。K線是紅的，但買賣窗口是綠的。主力作出的圖，在雙向成交量中，是上漲主動(dòng)買。而在資金流向中，流量是負(fù)值。
在30分鐘線上，我們就可以看出不同時(shí)段的情況。
在雙向成交公式中，我們就可以看到買與賣的具體量了。
《資金流向》不是我第一次拿出來的。在《資金流向和主力資金》中就已經(jīng)介紹過了。當(dāng)然，那里沒有講怎樣寫。
|
