打開技術(shù)指標公式，我們最常見的，它的組成不外乎兩種情況，一是K線，二是均線。其他諸如柱狀線，彩帶，分段線等等，都是在K線或均線基礎(chǔ)上的延伸或變形。為此，我們先熟悉一下構(gòu)成這兩種狀態(tài)的基本函數(shù)。

第一講  基本入門

　　一、K線函數(shù)
　　非常簡單，大家都可能熟知。作為基礎(chǔ)，還是說明一下。
　　1、開盤價：OPEN　可簡寫為　O
　　2、最高價：HIGH　可簡寫為   H
　　3、最低價:LOW　　可簡寫為   L
　　4、收盤價:CLOSE　可簡寫為   C
　　有了這4個函數(shù)，就可構(gòu)成一根K線了。比如：收盤價小于開盤價，即陰線：C<o;　收陽線則互為相反。
　　那么長下影的光頭陽線，即　T　形線呢？理解了原理，也很簡單。一要以最高價收盤（否則有上影），二要開盤價大于最低價。所以有如下表示：C=H AND O>L;這里我們沒有考慮下影的長度和　T　字上邊一橫（實體部分）的寬度。
　　習(xí)題：一根光頭陽線，實體部分小于5分錢，下影超過實體的兩倍，如何表述？
　
　　特別提示：編輯指標必須在英文狀態(tài)下輸入。其中運用的數(shù)學(xué)符號，包括加減乘除、分號，引號等（+ - * / ; "" ''><#）也必須在英文狀態(tài)下輸入。
二、均線函數(shù)
　　單根K線的形態(tài)是相當枯燥的。尤其在主圖里。配合以均線等形式就會豐富多采，或者更利于我們從中發(fā)現(xiàn)規(guī)律和分析問題。這就需要均線函數(shù)來解決了。
最常見的：
　　1、MA(X,N),求X的N周期簡單移動平均值。
　　算法：(X1+X2+X3+...+Xn)/N
　　例如:MA(CLOSE,20)，表示求20日均價。
　　2、EMA(X,N),求X的N周期指數(shù)平滑移動平均。
　　算法: 若Y=EMA(X,N) 則Y=[2*X+(N-1)*Y']/(N+1), 其中Y'表示上一周期Y值。
　　例如:EMA(CLOSE,20)，表示求20日指數(shù)平滑均價。
　　3、SMA(X,N,M),求X的N周期移動平均，M為權(quán)重。
　　算法: 若Y=SMA(X,N,M) 則 Y=(M*X+(N-M)*Y')/N, 其中Y'表示上一周期Y值,N必須大于M。
　　例如:SMA(CLOSE,20,1)，表示求20日移動平均價。
　　這三個均線函數(shù)在股軟中是通用的。關(guān)于它們的區(qū)別，開始學(xué)習(xí)時不必深究。其實數(shù)值區(qū)別也不是很大。要均線真實反映每天的價格變化，用MA，適當圓滑些，用EMA　或SMA。
　　三、常用連接函數(shù)
有了上述基本函數(shù)，可以表述出K線和均線了，但實際應(yīng)用中要復(fù)雜得多，還要一些函數(shù)把他們連接起來。
大致有這么幾個：
　　1、AND　就是“和”的意思。如：A　AND　B；就是A和B兩個條件要同時成立。
　　2、OR　“或”，“或者”的意思。如：A　OR　B；就是A和B兩個條件有其中一個成立就行。
　　3、IF　根據(jù)條件取不同的值。如：IF(X,A,B)，若X不為0則返回A,否則返回B。實例:IF(C<O,L,H)，表示收陰返回最低價，否則返回最高價。
　　4、CROSS　交叉函數(shù)。CROSS(A,B)，表示A從下方向上穿過B。
　　5、REF　向前引用。引用若干周期前的數(shù)據(jù)。例如:REF(CLOSE,1)，表示昨收的收盤價。那么前天的最高價呢，就是：REF(H,2)。
　　四、成交量　
　　VOL　表示每天的成交量。因以后會經(jīng)常用到，所以先交待給大家。
　　上面這幾個函數(shù)是最常用的，希望大家記住，不知怎么寫也要知道其表述的意思。當然，記不住也不要緊，《公式編輯器》中全有。
　　習(xí)題：10日均線與20日均線金叉和漲幅超過百分之三，且成交量比昨天放大一倍。

第二講 認識顏色符號或繪圖函數(shù)

　　我們所看到的指標是以線為基礎(chǔ)的。不論是均線，K線，或在線與點之間的填充，又都離不開顏色。正是有了五顏六色才使得圖形豐富多采，便于區(qū)分，或者更具立體感。本講就是告訴大家如何利用顏色或修改顏色。
　　一、顏色函數(shù)
　?。ㄒ唬┗痉枺篊OLOR
　　所有顯示顏色時，都必須用這個符號做為引導(dǎo)。但它本身并沒有色彩，在它的后面還需加上具體的顏色，才能使用。
　　舉例：COLORBLACK;后面加上英文的黑色單詞，在圖中就會顯示出黑色來了。
　?。ǘ┏Ｓ妙伾?br>顏　色　　　1：飛狐的：　　　2、大智慧2　　　3、大智慧　　4、通達信　　　　5、同花順　 6、通用符號　　

紅　色　　　COLORRED;　　　　　同前　　　     同前    與飛狐基本相通　　　同　前
白　色　　　COLORWHITE;　　　　同前　　    同前　　   一般不用修改　　　　以下略－－　
黃   色    　COLORYELLOW;　　　同前　　    同前　　　以下略－－
黑　色　　　COLORBLACK;　　　　同前
藍　色　　　COLORBLUE; 　　　同前　　　     同前 　　　 　　　　　　　　　　　　COLORFFFF00
棕　色　　　COLORBROWN;　　　　同前    COLOR0055FF
青　色(淡藍)COLORCYAN; 　　　　同前    COLORFFFF00 　　　　　　　　　　　　　　　COLORF0F000
灰　色　　　COLORGRAY;　　　　同前　　　    同前
綠　色　　　COLORGREEN;   　　　同前　　    同前　　　           　　　　　　　　　COLOR00FF00
晶紅色（粉）COLORMAGENTA; 　　同前    COLORff00ff　     　　　　　　　　　　　　COLORF00FF0

此外還有：金黃色COLOR008364　紫紅COLOR000999　深黃色COLOR00CCCC　紫羅藍COLORE66878　等等。

　?。ㄈ┏Ｒ婎伾珕栴}。
　　從上表中我們可以看出，大部分顏色符號是通用的。但在將源碼粘貼時，因股軟的不同，有時會出現(xiàn)《未定義的標識符》字樣，很多時候就是顏色惹的禍。常見的是：
COLORCYAN　　　淡藍色，大智慧不識別，需改成：COLORFF0000
COLORMAGENTA　晶紅色，大智慧不識別，需改成：COLORF00FF0
　　特別提示：找不到相對應(yīng)的顏色函數(shù)怎么辦？一是刪除，讓系統(tǒng)自動填加。二是更換數(shù)字或字母。
　　　　　　　實際上只要在COLOR后面加上0－9、A－F中的任意6個數(shù)字字母，就可組成不同的顏色。有興趣的可試試
　　（四）指標線粗細函數(shù)　LINETHICK　放在語句的后面，用　,　號隔開。例：LINETHICK2，后面的數(shù)值越大，線就越粗。
　　特別提示：LINETHICK0　表示不畫出指標線，但可在頂部顯示數(shù)值。

　　二、繪圖函數(shù)
　　1、DRAWICON　在圖形上繪制小圖標。這是最常用的繪圖函數(shù)之一。
　　用法：DRAWICON(條件,位置,圖標)
　　飛狐15種圖標編碼為1-15（1-3為小臉,4-5為上下箭頭,6-7為紅綠小旗,8-9為三角形,10-12為信號燈,13-15為O、X、四方形）。
　　大智慧2的圖標編碼為14個。
　　其他股軟略少。
　　這個函數(shù)通用。但同一數(shù)字編碼，顯示出的圖形區(qū)別卻非常大，形態(tài)也不一樣。大家可通過變動數(shù)字編碼自行調(diào)整。
　　2、DRAWTEXT　在圖形上顯示文字。這也是最常用的繪圖函數(shù)之一。
　　用法 DRAWTEXT(條件,位置,文字)，注意，文字必須用單引號　''　引上才能輸出。
　　飛狐可用'\n'換行,　飛狐和大智慧2可用　ALIGN　0-3　定義對齊方式。
　　3、STICKLINE　在圖形上繪制柱線。
　　用法：STICKLINE(條件,上位置,下位置,寬度,實體或空心)。
　　此函數(shù)股軟通用。寬度最大為10（一般K線的寬度為6）。　0?。媽嵭闹?，　　1?。嬁招闹?。
　　4、PARTLINE　分段繪制指標線。
　　飛狐用法 PARTLINE(條件,需要變色的線)。
　　例如 PARTLINE(C>REF(C,1),C),colorred　表示收盤大于前收以紅色繪制收盤價連線。
　　大智慧2用法：PARTLINE(需要變色的線,條件1,條件1用的顏色,條件2,條件2用的顏色...)，最多可以有10組條件。
　　例如：PARTLINE(C,C>O,RGB(255,0,0),C<ORGB(0,255,0),1,RGB(0,0,255))表示畫收盤價線，陽線時用紅色，陰線時用綠色，平盤用藍色。注意最后一個條件為1，表示前面都不滿足時必然滿足這個條件。
　　特別提示：大智慧2同分析家一樣，在繪制分段線時，用的不是正常的顏色函數(shù)，而是用RGB(255,0,0)來表達。以下是幾種常用顏色：
洋紅（255，0，255）　紅色（255，0，0）　綠色（0，255，250）　黃色（255，255，0）　紫色（128，0，128）　
灰色（169，169，169）　天藍（255，215，0）。
　　同花順和大智慧2一樣，運用相同的函數(shù)。
　　通達信的劃分段線是用IF條件函數(shù)來實現(xiàn)的。
　　例：IF(C>=O,A線,DRAWNULL),COLORRED,LINETHICK2;
　　翻譯過來是：當收盤價大于等于開盤價時，在A線上劃紅色，否則不劃。指標線為2等粗。
　　特別提示：DRAWNULL　是通達信的專用函數(shù)。意思是返回0。其他股軟遇到此函數(shù)時，可直接用0替代。
大智慧沒有這項功能。一般用如下三種方式替代：
　　第一種：用　DRAWTEXT　在圖形上顯示文字的方式。在文字欄用的文字是小圓圈。
　　第二種：用　STICKLINE　在圖形上繪制柱線的方式。但注意柱線必須要短。
　　第三種：用　IF　條件函數(shù)的方式，適用于3條線以上。本文略去。
　　5、FILLRGN　畫區(qū)間彩帶
　　飛狐用法:FILLRGN(條件,線1,線2)
　　例如:FILLRGN(MA1>MA2, MA1,MA2),colorred 表示MA1>MA2時以紅色填充MA1和MA2之間的區(qū)域。
　　大智慧2用法：FILLRGN(線1,線2,條件1,顏色1,條件2,顏色2...),填充條件1到條件2之間的區(qū)域，當條件1滿足時,用顏色1，當條件2滿足時,用顏色2，否則不填充，最多可以有10組條件。
　　例如：FILLRGN(CLOSE,OPEN,CLOSE>OPEN,RGB(255,0,0),CLOSE<OPEN,RGB(0,255,0))表示填充開盤價和收盤價之間的區(qū)域，陽線時用紅色，陰線時用綠色，平盤不繪制。
　　其他三種股軟好像都沒有這項功能。
　　為了實現(xiàn)這一效果，一般都是用劃柱線的方式替代。注意的是，一般要將寬窄的數(shù)字加大，目的是讓相鄰的柱線合在一起顯示出整體的效果。
例：STICKLINE(J<K,J,K,10,0),COLOR00FF00;即，當J小于K　時，在J與K之間填充柱線，寬度為最大粗值－－10。

第三講：源碼的引入和修改

　　　　　　　　　　　　　　　?。ㄒ唬┰诟鞣N股軟中的引入方法
　　
　　股軟之間雖然區(qū)別較大，但有一個共同點，就是第一步都是打開公式編輯器。下面再分別簡要說明一下：
　　一、大智慧

　　1. 把要導(dǎo)入的公式（源碼）考下來，方法是用左鍵先把源碼變藍，之后點右鍵，點復(fù)制；
　　2. 進入大智慧------>特色功能------>自編指標------>常用------>技術(shù)指標------>新建，在出現(xiàn)的公式編輯區(qū)的下面的空白處,把剛考的源碼粘貼上，將公式名稱復(fù)制后粘貼到公式名稱欄------>確認------>退出。
　　3、在大智慧的底部顯示欄中點擊公式名稱即可看到剛剛導(dǎo)入的公式。

　　二、飛狐
　　1、復(fù)制源碼，方法同上。
　　2、進入主界面，即K線圖模式。
　　用鼠標靠近左側(cè)單擊，出現(xiàn)管理面板------>雙擊技術(shù)指標------>用鼠標右鍵單擊任何一個公式組的名稱，比如“其它”------>點新建公式------>在出現(xiàn)的公式編輯區(qū)的下面的空白處,把剛考的源碼粘貼上，將公式名稱復(fù)制后粘貼到公式名稱欄------>確定------>退出。
　　3、找到新建的公式，雙擊即可使用。

　　三、大智慧2

　　特別提示：必須在聯(lián)網(wǎng)的狀態(tài)下才可操作
　　有兩種方式可以進入公式編輯頁面。一是將鼠標靠近上部，點擊《公式》―――《公式管理》―――雙擊《技術(shù)指標》―――單擊指標組―――《新建》。
　　另一種方式是，將鼠標靠近左邊，在出現(xiàn)的對話框中雙擊《技術(shù)指標》―――右鍵單擊選定的公式組―――《新建》。

　　三、分析家
　　復(fù)制公式原碼到分析家界面―――點擊上面的《公式》―――點擊《公式管理》―――按公式歸類把其點擊變色―――點擊《新建》。

　　四、通達信
　　將鼠標靠近左邊，在出現(xiàn)的對話圖標中選F(x)即《公式管理器》圖標―――雙擊《技術(shù)指標公式》―――單擊選定的指標組―――《新建》。

　　五、同花順
　　將鼠標靠近上部―――點擊《公式》圖標，進入后的操作與其他股軟基本一樣。
　　特別提示：必須在《描述》欄中加上文字或字母之類，否則無法通過。

　　　　　　　　　　　　　?。ǘ┕揭霑r的注意事項和說明

　　一、參數(shù)問題
　　復(fù)制的源碼中有參數(shù)的，例如：｛N   1   100   15｝，有三種解決辦法：
　　1、手工將參數(shù)分別填加到參數(shù)表中。
　　2、采取變通方式進行改動。｛N   1   100   15｝改動后為：N:=15;
　　特別提示：注意用參數(shù)的大小處于中間的值來替換。這個中間值也是缺省值。另外：N后面必須加上等號，它的意思是不顯示。
　　3、對于INPUT:N(5), M(10,1,100,2);這類有申明參數(shù)函數(shù)的，飛狐，大智慧2和分析家可不用理它，系統(tǒng)會自動將參數(shù)填加到參數(shù)表中。這里的M(10,1,100,2)里面的2是步長，手工填加時可刪去。

　　二、粘貼源碼時常見的問題和注意事項
　　1、未定義的標識符
　　多數(shù)是由參數(shù)引起的。還有就是有些源碼中附帶了公式名稱或說明，這些公式源碼以外的內(nèi)容，如：名稱，說明以及參數(shù)等等，凡在｛　｝以外的，均要刪除，或者用｛?。龑⑵淅ㄉ稀?br>　　2、條件選股類的公式，應(yīng)加入到和“技術(shù)指標”并列的“條件選股”組中。
　　3、是主圖公式的，需在公式編輯區(qū)中點“主圖疊加”。
　　4、通達信的輸出一般都限定在16條。多出的解決辦法是：將沒有必要輸出的語句后面加上“等號”，或者刪去。例：
　　買點: STICKLINE(Var6>REF(Var6,1) AND Var6>0 ,Var6,Var8,10,0);
　　DRAWICON(FILTER(Var6>REF(Var6,1) AND Var6>0,30),-140,4);
　　DRAWTEXT(FILTER(Var6>REF(Var6,1) AND Var6>0,30),-40,'建議關(guān)注 '),COLORffffff;
　　這三項分別是劃柱線、顯示小箭頭和顯示文字。留一個就行了。
　　加“等號”的例子：
　　Var2:MA(CLOSE,10);
　　Var3:MA(CLOSE,20);
　　Var4:MA(CLOSE,30);
　　加上后：
　　Var2:MA(CLOSE,10);
　　Var3:=MA(CLOSE,20);
　　Var4:MA(CLOSE,30);
　　意思是保留了10日均線和30日均線的輸出，將20日的隱去。
　　特別提示：不論什么股軟，當遇到線條過多過亂時，都可以采用這種辦法使圖形簡練清晰。
　　5、顏色符號及逗號問題
　　例：倉:EMA(100*(CLOSE-LLV(LOW,34))/(HHV(HIGH,34)-LLV(LOW,34)),3),,colormagenta;
　　此句可能存在兩個問題，一是后面有兩個“逗號”，對于飛狐等通過，而對于大智慧2和分析家等，則是問題，必須刪去一個。反之，一個沒有也不行。二是后面的colormagenta，大智慧是不認識的。換成通用的：colorf00ff0就行了。
　　6、是否輸出與顏色標識問題
　　例：倉:=EMA(100*(CLOSE-LLV(LOW,34))/(HHV(HIGH,34)-LLV(LOW,34)),3),colormagenta,LINETHICK0;
　　這個語句的特點是在前面有等號“　= ”，意思是不輸出，但后面還有顏色修飾符和指標線粗細函數(shù)。有些股軟對此是放行的，即：不輸出。而大智慧2和分析家卻不認，把它看成相互矛盾的病句。解決辦法：將修飾符全部刪去，或?qū)⑶懊娴摹?　號去掉，讓語句輸出。

第四講：各種形態(tài)的描述

懂得運用公式編輯器，掌握了公式的基本函數(shù)，就可以進行簡單的公式編寫了。下面我們共同認識一下公式的基本語句。這些基本語句，是編寫公式和整理選股公式信號的基礎(chǔ)，大家要熟知。
　　　　　　　　　　　　　　　　　　　　
　　　　　　　　　　　　　　　　　　一、K線的基本形態(tài)

　　1、當天收陽：CLOSE＞OPEN；
　　2、當天收陰：CLOSE＜OPEN；
　　3、當天股價高開，言下之意開盤高于昨日收盤：OPEN＞REF（CLOSE，1）；
　　4、當天股價低開：OPEN＜REF（CLOSE，1）；
　　5、跳空高開：OPEN＞REF（HIGH，1）；當日開盤在昨日最高價之上
　　6、跳空低開：POEN＜REF（LOW，1）；
　　7、長陽：C/O>1.03 或者 (C-O)/O*100>5 或者 (C-O)/O>0.05　意思是收盤價比開盤價上漲5%以上。當然，用7%以上也可。
　　8、長陰：C/O<0.94;　注意：同一語句可有多種表述，此為其一。
　　9、高開大陰：O/REF(C,1)>1.04   AND C/O<1.94; 今天開盤比昨天收盤高出4%和收盤價較開盤下降6%。低開大陽與此正好相反。
　　10、標準十字星：CLOSE=OPEN AND HIGH<>LOW
　　更多見的是近似十字星。例：ABS(C-O)<0.02 AND H-C>0.03 AND C-L>0.03; 該語句用上了一個函數(shù)：ABS，意思是求絕對值。這樣，該近似十字星即可能是陽星也可能是陰星。
　　再認識兩個函數(shù)：MAX(A,B) 求A和B中的最大值。
　　　　　　　　　　MIN(A,B) 求A和B中的較小值
　　有了這兩個函數(shù)，近似十字星還可這樣表述：ABS(C-O)<0.02 AND H> MAX(C,O) AND L< MIN(C,O);
　　另外，該公式還可以用比例數(shù)編寫。
　　11、長下影線：也有收陰收陽之分。以陽線長下影線為例：C>O AND (O-L)>(C-O);此公式只表達了下影線比實體線長，并沒有表達長度比例和有無上影線。

　　留個習(xí)題吧：不限制陰陽線，上影小于5分錢，下影線是實體的兩倍以上。

　　形態(tài)還有許多，有幾十種，不一一例舉了，大家舉一反三，慢慢摸索吧。

　　　　　　　　　　　　　　　　　　　二、條件選股的基本形態(tài)

　　1、階段最高價：HHV(H,N) 意思是取得N天之內(nèi)的最高價。新函數(shù)：HHV，最高值。
　　2、階段最低價：LLV(L,N)意思是取得N天之內(nèi)的最低價。新函數(shù)：LLV，最低值。
　　3、階段漲幅 (C-REF(C,N))/REF(C,N)*100　N日收盤價的差值的百分比。
　　4、再創(chuàng)新高 HIGH=HHV(HIGH,N) 是指今日最高價是N日以來的最高價.。 再創(chuàng)新低：略。
　　5、放量：
　　（1）今日比昨日的成交量放大了1倍： VOL/REF（VOL,1）>2；
　　（2）今日的五日均量比前五天的五日均量放大了3倍：
　　AA：=MA（VOL,5）；
　　BB：=REF（AA,5）；
　　AA/BB>4；
　?。?）今天的成交量達到了整個流通盤的10%以上： VOL/CAPITAL>10/100；
　　注意，10%的表達式是10/100，或者0.1
　　6、縮量：
　　（1）今日比昨日的成交量縮小了1倍： VOL/REF（VOL,1）<0.5；
　　（2）今日的五日均量比前五天的五日均量縮小了一半：
　　AA：=MA（VOL,1）<0.5；
　　BB：=REF（AA,5）；
　　AA/BB<0.5；
　　（3）今天的成交量不足整個流通盤的0.5%： VOL/CAPITAL<0.5/100；
　　7、放量上攻 　　是指價格上揚，成交量劇增
　　C/REF(C,5)>1.2 AND VOL>MA(VOL,5)*3; 表示5日上漲20%和成交量超過5日均量的3倍。
　　8、持續(xù)放量：COUNT(V>REF(V,1),N)=N;　實際上這種情況不是很多。如果用3日均量，或5日均量則非常普遍。即：COUNT(MA(V,3)>REF(MA(V,3),1),N)=N;
　　9、階段放量
　　N(1,100,10)   M(1,100,5)
　　SUM(VOL,N1)/CAPITAL>=(N/100)   M日內(nèi)換手率大于百分之N
　　10、溫和放量上攻
　　M(2,10,3) N(1,40,10)
　　UP:=MAX(C,O)>REF(MAX(C,O),1);
　　A:=VOL>REF(VOL,1);
　　COUNT(IF((UP AND A),1,0),N)=N AND C>O
　　AND (C-REF(MAX(C,OPEN),1))/REF(MAX(O,C),1)<=(3/100)
　　AND VOL/CAPITAL<=(M/100)
　　連續(xù)N個周期放大并保持上漲勢頭 當日換手率小于 M%
　　11、突然放量
　　N(1,300,10)M(1,40,3)
　　VOL>REF(HHV(VOL,N),1)*M
　　成交量較前N周期的最大成交量增大M倍
　　12、上漲： C/REF(C,1)>1.07；今日漲幅達到了7%以上。
　　注意：漲幅是指當天收盤價與昨天的收盤價之比。
　　13、下跌： 同上面的表達方式一樣，將方向改變了而已。
　　14、十日均價繼續(xù)上漲：
　　AA:=MA(C,10);
　　BB:=REF(AA,1);
　　AA>BB;
　　15、窄幅整理：就是指近一段時期價格維持在一定幅度之內(nèi) 　
　　(HHV(C,20)-LLV(C,20))/C<0.08 ;即20日內(nèi)價格振幅在8%以內(nèi)波動。
　　16、連續(xù)N天收陽：COUNT(C>O,N)=N;　
特別提示：新函數(shù)：COUNT(X,N),統(tǒng)計滿足條件的周期數(shù)。若N=0則從第一個有效值開始。
例:COUNT(C<O,10)　表示統(tǒng)計10周期內(nèi)收陰的周期數(shù)。此句使用時必須加上條件，即收陰時怎么了方才有效。如：AA AND COUNT(C<O,10) 的返回值仍是AA，只有AA AND COUNT(C<O,10)<=3;時，即加上條件“小于等于3”周期時，才有實際意義。這個函數(shù)經(jīng)常用到，務(wù)請留意。
　　17、N日內(nèi)陽線多于陰線：COUNT(C>O,N)>N/2;　
　　18、創(chuàng)歷史新高：C=HHV(C,0);　
　　特別提示：此公式本應(yīng)為：C=HHV(C,N);　當N等于0時，從第一天開始統(tǒng)計。統(tǒng)計歷史數(shù)據(jù)時，如果從頭開始，都用0。
　　19、尾盤拉升
　　HOUR>14 AND MINUTE>56 AND CLOSE/REF(CLOSE,2) >= 1+N/100
　　14:56以后2分鐘漲幅超過N%
　　20、突破長期盤整
　　N(10,60,30)   M(5,50,30)
　　REF(((HHV(H,N)-LLV(L,N))/LLV(L,N)),1)<=(M/100)AND C>=REF(HHV(H,N),1) AND BARSCOUNT(C)>N
　　前N日在上下M%的幅度內(nèi)整理，今日突破。
　　21、階段強勢股
　　N(700101,1341231,990519) M(700101,1341231,990913)
　　A:=SUM(IF(DATE-N=0,INDEXC,0),0);
　　B:=SUM(IF(DATE-M=0,INDEXC,0),0);
　　E:=SUM(IF(DATE-N=0,C,0),0);
　　F:=SUM(IF(DATE-M=0,C,0),0);
　　((F-E)/E)>((B-A)/A)
　　選擇N日----M日之間內(nèi)走勢強于大盤的股票.
　　22、大盤同步選股
　　N(1,100,10)M(1,100,50)
　　COUNT((C>O AND INDEXC>INDEXO) OR (C< O AND INDEXC< INDEXO),N)/N > M/100
　　N周期中與大盤走勢相同(同收陰線或同收陽線)的比例超過M%
　   23、今收盤對于N日內(nèi)最低收盤價的漲幅（%）
　　(C-LLV(C,N))/LLV(C,N)*100;
　　24、今收盤對于N日內(nèi)最高收盤價的跌幅（%）
　　(HHV(C,N)-C)/HHV(C,N)*100;
　　 25、股價在過去N日內(nèi)運行空間的相對位置
　　(C-LLV(L,N))/(HHV(H,N)-LLV(L,N))*100;　　
　　26、股價上方N1%至N2%處的籌碼（%）
　　AA:=WINNER(C+C*N2/100)*100;
　　BB:=WINNER(C+C*N1/100)*100;
　　AA-BB
　　認識新函數(shù)：WINNER(CLOSE)　獲利盤比例。表示以當前收市價賣出的獲利盤比例,如返回0.2表示20%獲利盤；例如:WINNER(10) 表示10元價格的獲利盤比例。該函數(shù)僅對比較日線分析周期有效?！　?br>　　27、股價下方N1%至N2%處的籌碼（%）
　　(WINNER(C-C*N1/100)-WINNER(C-C*N2/100))*100;
　　28、收盤價N%處的套牢盤
　　100-(WINNER(C*N/100))*100;
　　29、收盤價N%處的獲利盤
　　WINNER(C*N/100)*100;

　　　　　　　　　　　　　　　　　　　三、基本面選股舉例

　　1、小盤選股
　　CAPITAL<=500000 AND FINANCE(33)>=0.01 AND CLOSE<=30
　　2、低市盈率選股
　　DYNAINFO(39)<=N AND DYNAINFO(39)>0
　　3、業(yè)績選股
　　N(0,100,0.4)
　　FINANCE(33)>N 每股收益在0.4元以上
　　4、小盤股
　　N:=5000;
　　FINANCE(7)<=N
　　5、大盤股
　　N:=20000;
　　FINANCE(7)>=N
　　6、凈資產(chǎn)收益率選股
　　FINANCE(37)>(N/100) 凈資產(chǎn)收益率高于N的股票
　　7、每股凈資產(chǎn)選股
　　FINANCE(34)>N 選出每股凈資產(chǎn)大于N元的股票.
　　8、每股未分配利潤選股
　　FINANCE(32)>N 每股未分配利潤大于N的股票
　　9、市凈率選股
　　C/FINANCE(34)< N
　　市凈率=市價/每股凈資產(chǎn)   市凈率>N
　　市凈率越低公司股價越有被低估的可能,這類股票從理論上講具有更高的安全性.
　　10、換手率選股
　　DYNAINFO(37)>=N/100 單日換手率大于N的股票
　　換手率的計算公式或表達式：VOL/CAPITAL*100;　因此也可寫作：VOL/CAPITAL*100>=N/100
　11、掁幅：(H-L)/REF(C,1)*100; 注意：是比的昨天收盤價。

第五講  線性\顏色函數(shù)\公式實例

轉(zhuǎn)幾個針對線性和顏色函數(shù)方面的公式實例，做個參考吧。
1間隔點：
20,colorred,pointdot,linethick2;
80,colorred,pointdot,linethick2;
50,colorred,pointdot,linethick2;
2間隔線
20,colorred,linethick2；
80,colorred,linethick2;
50,colorred,linethick2;
3信號字
DRAWTEXT(RSI1<10,RSI1,'買'),Colorlime;
DRAWTEXT(RSI1>85,RSI1,'賣'),Colorlime;
4笑哭臉
DRAWICON(VR24<25,VR24,1),ColorFF0000;
DRAWICON(VR24>350,VR24,2),ColorFF0000;
5一線提示
cross("kdj.j"(9,3,3),"kdj.d"(9,3,3)) and "kdj.j"(9,3,3)<20,colorred
6一柱頂天
IF(VAR4=50,50,0),stick,linethick2;
7小人作怪
多頭卒:Var3,LINETHICK2, COLORf00ff0;
空頭卒:Var4,LINETHICK2, COLORYELLOW;
DRAWICON(Var9,Var9,1);
DRAWICON(Var10,Var10,2);

8小人
買入:Var1 AND Var2,stick,linethick2,colorred;
賣出:CROSS(80,Var4),stick,linethick2,colorgreen;
drawicon(賣出,1.1,2);
drawicon(買入,1.1,1);

9粗細面條
LINETHICK2

第3，4，6和7，還有8只要把RSI或VR或Var改成所在公式參數(shù)就可用；第5cross不能改，其它的可改；9你愛把線設(shè)多粗細都行。
1方塊STICKLINE
AA:=VOL/((HIGH-LOW)*2-ABS(CLOSE-OPEN));
買盤:IF(CLOSE>OPEN,AA*(HIGH-LOW),IF(CLOSE<OPEN,AA*((HIGH-OPEN)+(CLOSE-LOW)),VOL/2));
賣盤:IF(CLOSE>OPEN,0-AA*((HIGH-CLOSE)+(OPEN-LOW)),IF(CLOSE<OPEN,0-AA*(HIGH-LOW),0-VOL/2));
qq:=買盤+賣盤;
STICKLINE(賣盤<0,0,VOL,5,1),COLORlime;
STICKLINE(買盤>0,0,買盤,5,0),COLORRED;
結(jié)果:ma(qq,5)*5,COLORRED,LINETHICK2；

VOL后面的5，1是方塊大少。VOL是坐標，也就是方塊所放的地方。
2 3D效果
STICKLINE(OPEN>=CLOSE ,CLOSE ,OPEN,9,0 ),COLORaaaaaa;
STICKLINE(OPEN>=CLOSE ,CLOSE ,OPEN,6,0 ),COLORbbbbbb;
STICKLINE(OPEN>=CLOSE ,CLOSE ,OPEN,2.4,0 ),COLORcccccc;
STICKLINE(OPEN>=CLOSE ,CLOSE ,OPEN,1.1,0 ),COLORdddddd;

STICKLINE(CLOSE>OPEN,CLOSE,OPEN,9,0 ),COLOr6666cc;
STICKLINE(CLOSE>OPEN,CLOSE,OPEN,6 ,0 ),COLOR7777dd;
STICKLINE(CLOSE>OPEN,CLOSE,OPEN,2.4 ,0 ),COLOR8888ee;
STICKLINE(CLOSE>OPEN,CLOSE,OPEN,1.1 ,0 ),COLOR9999ff;

STICKLINE(CLOSE>OPEN,OPEN,LOW,0.5,0 ),COLOR1199ff;
STICKLINE(CLOSE>OPEN,CLOSE,HIGH,0.5 ,0 ),COLOR1199ff;
STICKLINE(OPEN>=CLOSE,CLOSE,LOW,0.5 ,0 ),COLORcccccc;
STICKLINE(OPEN>=CLOSE,OPEN,HIGH,0.5 ,0 ),COLORcccccc;

3顏色
大智慧只能用淺色調(diào)，一用深綠深藍就看不見了。所以我調(diào)了幾個淺色的，夠大智慧用的。
COLOR+RED;WHITE;LIME;YELLOW;aabbcc;ffaabb;abcdef;999999;C0C0C0.

4變色
變色可分3種：
1用DRAWTEXT：
ma10:ma(c,10),colorwhite;
llv(h,30),colorffcc66;
llv(l,30),coloryellow;
vhh:hhv(h,30),colorred;
vhl:hhv(l,30),color00ff00;
v1:=ma(HIGH,30)*1.15 ;
v2:=ma(HIGH,3)*1.03;
v3:=ma(LOW,3)*0.97;
v4:=ma(LOW,30)*0.85;
小通道上:=ma(v2,30);
小通道下:=ma(v3,30);
A2:=小通道上-REF(小通道上,1);
A3:=小通道下-REF(小通道下,1);
K:A2>0 and ref(A2<0,1),colorblue;
K1:A3>0 and ref(A3<0,1),colorff00ff;
K2:c<小通道下 and h<小通道下,color0099ff;
K3:c<小通道下 and A3>0,colorffcccc;
K4:h<小通道下 and A3>0,colorffbbff;
DRAWTEXT(A2>0 ,小通道上,'°'),colorred;
DRAWTEXT(A2<0 ,小通道上,'°'),color00ff00;
DRAWTEXT(A3>0 ,小通道下,'°'),colorred;
DRAWTEXT(A3<0 ,小通道下,'°'),color00ff00;
DRAWTEXT(A2=0 ,小通道上,'°'),COLORWHITE;
DRAWTEXT(A2=0 ,小通道下,'°'),COLORWHITE;
DRAWTEXT(A3=0 ,小通道上,'°'),COLORWHITE;
DRAWTEXT(A3=0 ,小通道下,'°'),COLORWHITE;

2用STICKLINE
AA:=WINNER(C)*100;
KA:=winner(O)*100;
高:=winner(H)*100;
低:=winner(L)*100;
莊籌線:EMA(AA*0.7,3),linethick2;
散籌線:EMA((WINNER(C*1.08)-WINNER(C*0.92))*70,3),linethick2;
stickline(AA<KA,高,低,0,0),colorlime;
stickline(AA<KA,AA,KA,6,0),colorlime;
stickline(AA>=KA,高,低,0,0),colorred;
stickline(AA>=KA,AA,KA,6,0),colorred;
stickline(莊籌線>散籌線,莊籌線,散籌線,0,0),colorwhite;

3用IF
主圖公式1：
A1:=Ma(C,5);{5日移動平均線}
A2:=Ma(C,10);{10日移動平均線}
A3:=(A1+A2)/2;{5、10日移動平均線之和除2的平均線，也就是中心線}
IF (A1>A2,A1,A3),Colorred,linethick2;{5日線大于10日且5日線交叉A3線顯示粗紅線}
IF (A1>A2,A2,A3),Colorred,linethick2;{5日線大于10日且10日線交叉A3線顯示粗紅線}
IF (A1<=A2,A1,A3),Color00ff00,linethick2;{5日線小于等于10日且5日線交叉A3線顯示粗綠線}
IF (A1<=A2,A2,A3),Color00ff00,linethick2;{5日線小于等于10日且10日線交叉A3線顯示粗綠線}
A3,colorwhite,linethick2;{中心線顯示粗白線}
這是以中心線為軸通過A1、A2這兩條線與中心線的交叉來變換顏色的。
主圖公式2：
MA1:=MA(CLOSE,5);{5日移動平均線}
MA2:=MA(CLOSE,10);{10日移動平均線}
MA3:=MA(CLOSE,20);{20日移動平均線}
MA4:=MA(CLOSE,30);{30日移動平均線}
MAA:=MA(CLOSE,60);{60日移動平均線}
MA5:IF(MA1<MA4,MA1,MA4),COLOR00ff00;{MA1線小于MA4且MA1線交叉MA4線顯示綠色線}
IF(MA1<MA4,MA4,MA1),coloryellow;{MA1線小于MA4且MA4線交叉MA1線顯示黃色線}
MA10:if(ma2<ma4,ma2,ma4),colorffcc66;{MA2線小于MA4且MA2線交叉MA4線顯示青色線}
if(ma2<ma4,ma4,ma2),color0099ff;{MA2線小于MA4且MA4線交叉MA2線顯示橘黃色線}
MA20:if(ma3<ma4,ma3,ma4),colorwhite;{MA3線小于MA4且MA3線交叉MA4線顯示白色線}
if(ma3<ma4,ma4,ma3),colorblue;{MA3線小于MA4且MA4線交叉MA3線顯示青色線}
MA30:if(ma4<maa,ma4,maa),colorff00ff,linethick2;{MA4線小于MAA且MA4線交叉MAA線顯示粉色粗線}
if(ma4<maa,maa,ma4),colorred,linethick2;{MA4線小于MAA且MAA線交叉MA4線顯示紅色粗線}
MA60:if(ma4>maa,maa,maa),linethick2,colorblue;{MA4線大于MAA且MAA線交叉MAA線顯示蘭色粗線}
這是分別以MA4、MAA線為軸通過向上交叉和向下交叉來變換顏色的。
單條變色線
ma10:ma(c,10);
if(ma10>ref(ma10,1),ma10,0),Circledot,COLORRED,LINETHICK2;
if(ma10<ref(ma10,1),ma10,0),Circledot,COLOR00FF00,LINETHICK2;

第六講   線形函數(shù)

一、線形函數(shù)
線形函數(shù)要和其它指標函數(shù)一起用才能發(fā)揮效力，因為它們都是描述其它指標函數(shù)的。正確用好線形函數(shù)可以使主副圖指標顯示豐富多彩，色彩繽紛。
1、函數(shù):STICK 說明：畫棒狀線，STICK的英文是棍、棒的意思。
如副圖公式:C>REF(C,1) AND C>REF(C,2),STICK;
2、函數(shù):COLORSTICK 說明：以零軸為中心畫彩色棒狀線，零軸下為陰線顏色，零軸上為陽線顏色,這樣零軸就如楚漢交界，涇渭分明了。
如副圖公式:C-REF(C,1),COLORSTICK;
3、函數(shù):LINESTICK 說明：同時畫棒狀線與指標線。LINE是線，STICK是棒，LINESTICK自然是線棒一起顯示了。如副圖公式:
A:=C-REF(C,1);
A,LINESTICK;
即想顯示指標線和棒狀線，又想以零軸為中心上下顯示兩種彩色棒狀線，可以用分開的兩句語句來達到目的,如副圖公式:
A:=C-REF(C,1);
A,LINESTICK;
A,COLORSTICK;
4、函數(shù):VOLSTICK 說明:畫成交量柱狀線。這是專門為顯示成交量設(shè)計的。如副圖公式:
VOL,VOLSTICK;
5、函數(shù):CROSSDOT 說明:畫叉狀線或x狀線。CROSS是交叉，DOT是點。如副圖公式:
ma1:ma(c,30),CROSSDOT;
6、函數(shù)：CIRCLEDOT 說明：畫小圓圈線,如副圖公式:
ma1:ma(c,30),CIRCLEDOT;
7、函數(shù)：LINETHICK 說明:改變指標線粗細。取1、2、3、4、5、6、7放在LINETHICK后面如:LINETHICK2,數(shù)字越大，線越粗，最大可取7。如副圖公式:
例1:ma1:ma(close,30),COLORFF00FF,linethick2;
例2:A:=C-REF(C,1);
A,COLORSTICK,LINETHICK4;
8、函數(shù)：POINTDOT 說明:畫點狀線,POINT是點、加點的意思。這個點狀線看起來有點太小了，可以用加粗線函數(shù)。如副圖公式:
ma1:ma(c,30),COLOR00FF00,POINTDOT,LINETHICK2;
我們編個指標，看看都用了哪些線形函數(shù)。
{頂?shù)字笜藑
股價趨勢:3*SMA((CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100,5,1)-2*SMA(SMA((CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100,5,1),3,1),COLORFF00FF,LINETHICK2;
底部警戒:10,COLORFFCCCC,POINTDOT;
買入警戒:IF(股價趨勢<=10,40,0),stick,linethick3,coloryellow;
買入信號:IF(CROSS(股價趨勢,底部警戒),80,0),stick,linethick3,colorblue;
強弱分界:50,COLORWHITE,POINTDOT,LINETHICK2;
頂部警戒:90,COLORFFCC66,POINTDOT;
賣出警戒:IF(股價趨勢>=85,40,0),stick,linethick3,colorred;
賣出信號:IF(CROSS(股價趨勢,頂部警戒),80,0),stick,linethick3,color00ff00;
指標解析：
{頂?shù)字笜藑
股價趨勢:3*移動平均((收盤價-最低值(最低價,27))/(最高值(最高價,27)-最低值(最低價,27))*100,5,1)-2*移動平均(移動平均((收盤價-最低值(最低價,27))/(最高值(最高價,27)-最低值(最低價,27))*100,5,1),3,1),COLORFF00FF,LINETHICK2;
底部警戒:10,COLORFFCCCC,點狀線;
買入警戒:條件函數(shù)(股價趨勢<=10,40,0),棒狀線,linethick3,coloryellow;{黃粗棒狀}
買入信號:條件函數(shù)(交叉函數(shù)(股價趨勢,底部警戒),80,0),棒狀線,linethick3,colorblue;{藍粗棒狀}
強弱分界:50,COLORWHITE,點狀線,LINETHICK2;{粗點狀線}
頂部警戒:90,COLORFFCC66,點狀線;
賣出警戒:條件函數(shù)(股價趨勢>=85,40,0),棒狀線,linethick3,colorred;{紅粗棒狀}
賣出信號:條件函數(shù)(交叉函數(shù)(股價趨勢,頂部警戒),80,0),棒狀線,linethick3,color00ff00;{綠粗棒狀}

二繪圖函數(shù)
繪圖函數(shù)的功能是在主圖或副圖上設(shè)定條件輸出圖標、直線、文字、數(shù)字、指標線、指標柱等。運用恰當使編制出的主副圖指標給以視覺上的美感。
1、函數(shù)RAWICON
用法RAWICON(COND,PRICE,TYPE),當COND條件滿足時,在PRICE位置畫TYPE號圖標。
說明:在圖形上繪制小圖標，其中TYPE可選3種圖標,編碼為1-3(1為紅臉、2為綠臉、3為平臉)。
示例：DRAWICON(CLOSE>OPEN,LOW,1);表示當收陽時在最低價位置畫1號圖標，也就是紅臉。
   DRAWICON(CLOSE<OPEN,high,2);表示當收陰時在最高價位置畫2號圖標，也就是綠臉。
指標示例：
{月均線主圖}
ma1:ma(close,5),colorwhite,linethick2;{畫一條5日收盤價的均線，設(shè)置該線為粗白色}
ma2:ma(close,10),colorff00ff,linethick2;{畫一條10日收盤價的均線，設(shè)置該線為粗粉色}
ma3:ma(close,20),color00ff00,linethick2;{畫一條20日收盤價的均線，設(shè)置該線為粗綠色}
a1:=cross(ma1,ma2);{5日均線上穿10日均線，金叉}
a2:=cross(ma2,ma1);{10日均線下穿5日均線，死叉}
DRAWICON(a1,low,1);{當a1條件滿足時，在最低價位置上顯示紅臉，表示此處可作為買入點}
DRAWICON(a2,high,2);{當a2條件滿足時，在最高價位置上顯示綠臉，表示此處可作為賣出點}
2、函數(shù)：DRAWLINE
用法RAWLINE(COND1,PRICE1,COND2,PRICE2,EXPAND),當COND1條件滿足時,在PRICE1位置畫直線起點，當COND2條件滿足時,在PRICE2位置畫直線終點，EXPAND為延長類型。 
說明：在圖形上繪制直線段。
示例： DRAWLINE(HIGH>=HHV(HIGH,20),HIGH,LOW<=LLV(LOW,20),LOW,1);表示在創(chuàng)20天新高與創(chuàng)20天新低之間畫直線并且向右延長。
DRAWLINE是唯一一個一句里面用到兩個COND的繪圖函數(shù)。因為它需要兩個點來決定一直線。
COND1相當于指定K線位置（橫坐標），PRICE1相當于是指定價位（縱坐標），這樣一個點在平面上的位置就決定了。
DRAWLINE是從第一點畫到第二點的，即有起點與終點的順序關(guān)系：第一點出現(xiàn)的時間，要在第二點之前。否則線是畫不出來的。
EXPAND，擴張、發(fā)展，這里是延伸的意思吧。取0，不延長；取1，延長。實際上是取大于等于1的數(shù)就延長，小于1就不延長。
指標示例：
{季均線主圖}
ema1:ema(close,20),colorff00ff;{畫一條20日收盤價的均線,設(shè)置該線為粉色}
ema2:ema(close,40),color00ff00;{畫一條40日收盤價的均線,設(shè)置該線為綠色}
ema3:ema(close,60),colorwhite,CIRCLEDOT;{畫一條60日收盤價的均線，設(shè)置該線為白色o線}
DRAWLINE(HIGH>=HHV(HIGH,20),HIGH,HIGH>=HHV(HIGH,20),HIGH,1),colorwhite;{表示在創(chuàng)20天新高與創(chuàng)20天新低之間畫直線并且向右延長。}
DRAWLINE(HIGH>=HHV(HIGH,20),HIGH,LOW<=LLV(LOW,20),LOW,1),coloryellow;{表示在創(chuàng)20天新高與創(chuàng)20天新低之間畫直線并且向右延長。}
3、函數(shù)RAWTEXT 說明:在圖形上顯示文字。
用法RAWTEXT(COND,PRICE,TEXT),當COND條件滿足時,在PRICE位置書寫文字TEXT,可顯示多行文本。
示例RAWTEXT(CLOSE/OPEN>1.08,LOW,'大漲啦');表示當日漲幅大于8%時在最低價位置顯示'大漲啦'字樣。在某些滿足條件的地方直接顯示文字或字符，比顯示圖標要更直觀一些。注意，顯示的文字要用英語狀態(tài)下的單引號括起。
指標示例：
{長短結(jié)合主圖}
sma1:sma(close,5,1),color00ff00;{畫一條5日收盤價的均線，設(shè)置該線為綠色}
sma2:sma(close,10,1),coloryellow;{畫一條10日收盤價的均線，設(shè)置該線為黃色}
sma3:sma(close,60,1),colorblue,linethick2;{畫一條60日收盤價的均線，設(shè)置該線為藍色粗線}
DRAWTEXT(CLOSE/OPEN>1.08,LOW,'大漲啦'),colorwhite;{表示當日漲幅大于8%時在最低價位置顯示'大漲啦'字樣。}
4、函數(shù):POLYLINE 說明:在圖形上繪制折線段。
用法:POLYLINE(COND,PRICE),當COND條件滿足時,以PRICE位置為頂點畫折線連接。
示例:POLYLINE(HIGH>=HHV(HIGH,20),HIGH);表示在創(chuàng)20天新高點之間畫折線。
指標示例：
{長短結(jié)合主圖}
sma1:sma(close,5,1),color00ff00;{畫一條5日收盤價的均線，設(shè)置該線為綠色}
sma2:sma(close,10,1),coloryellow;{畫一條10日收盤價的均線，設(shè)置該線為黃色}
sma3:sma(close,60,1),colorblue,linethick2;{畫一條60日收盤價的均線，設(shè)置該線為藍色粗線}
POLYLINE(HIGH>=HHV(HIGH,20),HIGH),COLORWHITE;{表示在創(chuàng)20天新高點之間畫折線(白色)。}
5、函數(shù):STICKLINE 說明:在圖形上繪制柱線。
用法： STICKLINE(COND,PRICE1,PRICE2,WIDTH,EMPTY),當COND條件滿足時,在PRICE1和PRICE2位置之間畫柱狀線，寬度為WIDTH可為0---100(10為標準間距),EMPTH不為0則畫空心柱。
示例:STICKLINE(CLOSE>OPEN,CLOSE,OPEN,4,1);表示畫K線中陽線的空心柱體部分。

運用要點：
⑴PRICE1和PRICE2沒有順序關(guān)系，即何者在前何者在后都不影響語句的執(zhí)行。
⑵WIDTH寬度，支持小數(shù)。用1和用0.1，會有很大的差別。取4時和主圖的K線寬度差不多。
以下的副圖公式，畫出的K線，與主圖中顯示的K線差不多。
指標示例：
{副圖K線}
STICKLINE(C>O OR (C=O AND C>REF(C,1)),O,C,4,1),colorred;{畫出紅K實體}
STICKLINE((C>O AND C<>H) OR (C=O AND C>REF(C,1)),C,H,0.1,0),colorred;{畫出紅K上影線}
STICKLINE((C>O AND L<>O) OR (C=O AND C>REF(C,1)),L,O,0.1,0),colorred;{畫出紅K下影線}
STICKLINE(C<O OR (C=O AND C<=REF(C,1)),C,O,4,0),colorffcc66;{畫出青K實體}
STICKLINE(C<O OR (C=O AND C<=REF(C,1)),L,H,0.1,0),colorffcc66;{畫出青K影線。因為青K是實心的，所以影線從中穿過}
ma5:MA(C,5),colorwhite;
ma10:ma(c,10),colorff00ff;
繪圖函數(shù)結(jié)合示例介紹完了，相信你一定有所收獲吧，舉一反三自己動手編個指標。不要怕失敗，失敗是成功之母。
三背景裝飾
飛狐、分析家股軟能將背景顏色通過漸變顏色函數(shù)裝扮的很漂亮，那么大智慧股軟能做到嗎？能，但做出的背景色雖不如飛狐、分析家平滑漂亮，也能起到裝扮的作用，效果也可以。
在大智慧設(shè)計背景色的原理主要是通過主、副圖的坐標用畫柱線函數(shù)STICKLINE或者設(shè)定坐標用顏色代碼就可以完成。下面用實例來說明背景色的設(shè)計過程。
一、單色背景色，這是最簡單實用的一種裝飾方法。我們先來設(shè)計一個主圖指標：
要領(lǐng)：1、設(shè)定坐標：STICKLINE(CLOSE>0,h*9.0,l*0.01,8,0),color7d7f0f;意思是CLOSE>0條件滿足時，在坐標h*9.0至坐標l*0.01處畫寬度為8的實體柱線(也就是在整個主圖上添色)。
也可以這樣設(shè)定STICKLINE(110,0,110,8,0),color7d7f0f;顯示的是同樣效果。
2、添色的源碼必須在指標的頭條位置上，否則會覆蓋均線、K線、文字等圖形。
3、必須另外編制K線，因為背景色會覆蓋系統(tǒng)中的K線圖。
4、可以把背景色分為五檔、十擋或更多，同時注意與你的指標的最大值、最小值(也就是坐標)相匹配，否則會在指標中出現(xiàn)背景色殘缺不全的情況。
5、用你喜歡的顏色需要結(jié)合調(diào)色器可隨意自定義自己喜歡的顏色。不過可得有耐心?。?br>指標示例一：
{多空密碼主圖}
STICKLINE(CLOSE>0,h*9.0,l*0.01,8,0),color7d7f0f;{設(shè)置背景，可以將這句源碼復(fù)制粘貼到任意主圖指標的頭條位置上}
Var1:=(3*CLOSE+LOW+OPEN+HIGH)/6;
Var3:=(20*Var1+19*REF(Var1,1)+18*REF(Var1,2)+17*REF(Var1,3)+16*REF(Var1,4)+15*REF
(Var1,5)+14*REF(Var1,6)+13*REF(Var1,7)+12*REF(Var1,8)+11*REF(Var1,9)+10*REF
(Var1,10)+9*REF(Var1,11)+8*REF(Var1,12)+7*REF(Var1,13)+6*REF(Var1,14)+5*REF
(Var1,15)+4*REF(Var1,16)+3*REF(Var1,17)+2*REF(Var1,18)+REF(Var1,20))/221;
Var4:=MA(Var3,78),LINETHICK2;
Var5:=EMA(MA(CLOSE,3),34);
Var6:=MA(Var3,5);
Var7:=MA(Var3,9);
M60:MA(C,60),COLOREEFFFF,CIRCLEDOT;
STICKLINE(Var3>1.005*Var4,Var3,Var4,4,1),COLORYELLOW;
STICKLINE(IF(Var3<Var5,Var3<=1.015*Var4,Var3<=1.005*Var4),Var7,Var4,2,1),COLORffff88;
STICKLINE(Var3>Var6,Var3,Var7,4,1),COLORff88ff;
STICKLINE(IF(Var3<Var6,Var3<=1.015*Var6,Var3<=1.005*Var6),Var3,Var7,3,1),COLORFF6633;
STICKLINE(Var3>Var6,Var3,Var7,4,1),COLOR0000ff;
{下面是柱形K線，如果喜歡這樣的K線，你可以復(fù)制粘貼到任意主圖指標里面}
STICKLINE(C>=O,C,O,7,0),COLORRED;
STICKLINE(C>=O,C,O,4,0),COLOR7070ff;
STICKLINE(C>=O,C,O,2,0),COLORYELLOW;
STICKLINE(C>=O,H,L,0,0),COLORYELLOW;
STICKLINE(C<=O,C,O,7,0),COLORFF2020;
STICKLINE(C<=O,C,O,4,0),COLORFF6600;
STICKLINE(C<=O,C,O,2,0),colorffcc66;
STICKLINE(C<=O,H,L,0,0),colorffcc66;
M9:MA(C,9),COLORYELLOW;
生命線: MA(CLOSE,13),COLORYELLOW,LINETHICK2;
牛熊線: (EMA(CLOSE,5)*7+EMA(CLOSE,5)*3)/10,COLORFF00CC,LINETHICK2;
箱頂:MA(REF(HHV(CLOSE,30),1),2);
箱底:MA(REF(LLV(CLOSE,30),1),2);
AA:(MA(C,13)+MA(C,21)+MA(C,34)+MA(C,55))/4,COLORFF00FF;
半年線:ma(close,125),colorffcc66;
指標示例二：
{財出水面副圖}
VAR2:=(CLOSE-LLV(LOW,20))/(HHV(HIGH,20)-LLV(LOW,20))*100;
VAR3:=SMA(SMA(VAR2,3,1),3,1)/28.57;
VAR4:=EMA(VAR3,5);
操盤:=3*VAR3-2*VAR4;
A1:=CROSS(操盤,VAR3) AND VAR3<2.1 and c>o;
40,colorred,pointdot;
STICKLINE(c>0,40,22,8,0),colorff8080;{設(shè)置背景,CLOSE>0條件滿足時，在坐標40至坐標22處設(shè)置寬度為8的蘭色背景}
STICKLINE(c>0,22,4,8,0),color916f87;{設(shè)置背景,CLOSE>0條件滿足時，在坐標22至坐標4處設(shè)置寬度為8的深紫色背景}
stickline(a1,18,15,28,0),colorred;
stickline(a1,18,18,18,0),colorblue;
stickline(a1,8,8,9,0),colorffff00;
stickline(a1,6,6,4,0),colorffff00;
stickline(a1,10,10,12,0),colorffff00;
stickline(a1,12,12,20,0),colorffff00;
stickline(a1,14,14,24,0),colorffff00;
stickline(a1,16,34,0.1,0),colorc0c0c0;
stickline(a1,33,18,9,0),colorwhite;
drawtext(a1,36,'財出水面'),COLORWHITE;
VarE:=30+(REF(CLOSE,1)-REF(OPEN,1))/REF(OPEN,1)*100/1.5;
VarF:=30+(REF(CLOSE,2)-REF(OPEN,2))/REF(OPEN,2)*100/1.5;
Var10:=CROSS("KDJ.K"(9,3,3),"KDJ.J"(9,3,3)) AND "KDJ.D"(9,3,3)>13;
Var11:=CROSS(REF("KDJ.K"(9,3,3),1),REF("KDJ.J"(9,3,3),1)) AND REF("KDJ.D"(9,3,3),1)>13;
Var12:=CROSS(REF("KDJ.K"(9,3,3),2),REF("KDJ.J"(9,3,3),2)) AND REF("KDJ.D"(9,3,3),2)>12;
Var13:=Var10 OR Var11 OR Var12;
Var14:=REF("BIAS.BIAS2"(6,12,24),1)>2;
Var15:=REF("RSI.RSI1"(6,12,24),1)>(VarE+VarF)/1.8 AND REF("ROC.ROC"(12,6),1)-"ROC.ROC"(12,6)>0 AND Var13 AND Var14;
賣出:=Var15*100/15,color00ff00;
stickline(賣出,18,15,28,0),coloryellow;
stickline(賣出,18,18,18,0),colorblue;
stickline(賣出,8,8,9,0),colorffff00;
stickline(賣出,6,6,4,0),colorffff00;
stickline(賣出,10,10,12,0),colorffff00;
stickline(賣出,12,12,20,0),colorffff00;
stickline(賣出,14,14,24,0),colorffff00;
stickline(賣出,16,28,0.1,0),colorc0c0c0;
stickline(賣出,28,18,9,0),color00ff00;
drawtext(賣出,31,'落袋為安'),COLOR00FF00;
指標示例三：
{金叉死叉}
STICKLINE(100,0,100,8,0),colorff0098;{設(shè)置背景,100條件滿足時，在坐標100至坐標0處設(shè)置寬度為8的紫蘭色背景}
Var1:=EMA(HHV(HIGH,500),21);
Var2:=EMA(HHV(HIGH,250),21);
Var3:=EMA(HHV(HIGH,90),21);
Var4:=EMA(LLV(LOW,500),21);
Var5:=EMA(LLV(LOW,250),21);
Var6:=EMA(LLV(LOW,90),21);
Var7:=EMA((Var4*0.96+Var5*0.96+Var6*0.96+Var1*0.558+Var2*0.558+Var3*0.558)/6,21); Var8:=EMA((Var4*1.25+Var5*1.23+Var6*1.2+Var1*0.55+Var2*0.55+Var3*0.65)/6,21);
Var9:=EMA((Var4*1.3+Var5*1.3+Var6*1.3+Var1*0.68+Var2*0.68+Var3*0.68)/6,21);
VarA:=EMA((Var7*3+Var8*2+Var9)/6*1.738,21);
VarB:=REF(LOW,1);
VarC:=SMA(ABS(LOW-VarB),3,1)/SMA(MAX(LOW-VarB,0),3,1)*100;
VarD:=EMA(IF(CLOSE*1.35<=VarA,VarC*10,VarC/10),3);
VarE:=LLV(LOW,30);
VarF:=HHV(VarD,30);
Var10:=IF(MA(CLOSE,58),1,0);
Var11:=EMA(IF(LOW<=VarE,(VarD+VarF*2)/2,0),3)/618*Var10;
Var12:=IF(Var11>40,10,Var11);
STICKLINE(Var12>8,0,Var12,4,1), , COLORFF00FF;
Var13:=HHV(HIGH,30);
Var14:=LLV(LOW,30);
能量K:EMA((CLOSE-Var14)/(Var13-Var14)*97,5),COLORRED,linethick2;
能量D:EMA((CLOSE-Var14)/(Var13-Var14)*100,15),linethick2,colorff9933;
底部峰:5,pointdot,linethick2,COLORFF00FF;
DRAWTEXT(CROSS(底部峰,能量K),能量d,'●'),COLORWHITE;
DRAWTEXT(CROSS(底部峰,能量K),能量K+15,'底部形成'),COLORWHITE;
大智慧:100,,pointdot,linethick2,color00ccff;
強弱分界:50,pointdot,COLORWHITE;
DRAWTEXT(CROSS(90,能量K),80,'●'),COLOR00FF00;
DRAWTEXT(CROSS(90,能量K),90,'有風險'),COLOR00FF00;
DRAWTEXT(CROSS(90,能量K),能量K+13,'●'),COLOR00FF00;
DRAWTEXT(CROSS(能量D,能量K),98,'死叉'),COLORFFCC66;
DRAWTEXT(CROSS(能量D,能量K),90,'●'),COLORFFCC66;
DRAWTEXT(CROSS(能量K,能量D),8,'金叉'),COLORYELLOW;
DRAWTEXT(CROSS(能量K,能量D),15,'●'),COLORYELLOW;
0,pointdot,linethick2,COLORFF00FF;
漸變色源碼供參考:
STICKLINE(0 ,0,-1,15,0) ,COLORFF0098;
STICKLINE(10 ,10,0,15,0) ,COLORFF009A;
STICKLINE(20 ,20,10,15,0),COLORFF009C;
STICKLINE(30 ,30,20,15,0),COLORFF009E;
STICKLINE(40 ,40,30,15,0),COLORFF00A0;
STICKLINE(50 ,50,40,15,0),COLORFF00A2;
STICKLINE(60 ,60,50,15,0),COLORFF00A4;
STICKLINE(70 ,70,60,15,0),COLORFF00A6;
STICKLINE(80 ,80,70,15,0),COLORFF00A8;
STICKLINE(90 ,90,80,15,0),COLORFF00AA;
STICKLINE(100 ,100,90,15,0),COLORFF00AC;
STICKLINE(110 ,110,100,15,0),COLORFF00AF;
單色源碼供參考:
STICKLINE(CLOSE>0,h*9.0,l*0.01,8,0),color7d7f0f;
K線
STICKLINE(C>=O,C,O,7,0),COLORRED;
STICKLINE(C>=O,C,O,4,0),COLOR7070ff;
STICKLINE(C>=O,C,O,2,0),COLORYELLOW;
STICKLINE(C>=O,H,L,0,0),COLORYELLOW;
STICKLINE(C<=O,C,O,7,0),COLORFF2020;
STICKLINE(C<=O,C,O,4,0),COLORFF6600;
STICKLINE(C<=O,C,O,2,0),colorffcc66;
STICKLINE(C<=O,H,L,0,0),colorffcc66;
副圖背景色源碼供參考:
STICKLINE(100,0,100,8,0),color7d7f0f;{注意指標的坐標，按不同的坐標做相應(yīng)的調(diào)整，本例是100的坐標

第七講：均線（選股）的基本形態(tài)

　　提示：K線的初步平均。(O+H+L+C*2)/5;　或　 (H+L+C*2)/4;　　
　　一般認為：收盤價是最有說服力的和最有價值的，它是每天激烈爭奪的最后妥協(xié)。但也有人認為：收盤價固然重要，其他價格也是爭奪的產(chǎn)物。所以將全天的幾種價格因素都考慮進去更能反映每天的真實情況。
　　
　　1、最簡單的指標線
　　（1）均價線　就是 移動平均線MA，“MA”表示的就是計算平均值。
　　MA1=MA（CLOSE，5）；5日平均線=（今天收盤價+昨天收盤價+.....--5天前的收盤價）/5；
　　MA2=MA（CLOSE，10）；10日平均線=（今天收盤價+昨天收盤價+......+10天前的收盤價）/10；
　?。?）均量線　均價線會了，照著葫蘆畫瓢，把收盤價CLOSE換成成交量VOL就行了！
　　例：MA1：MA（VOL，5）；
　　MA2：MA（VOL，10）；
　　
　　2、再次平均　指將已有的均線（多條均線）相加后進行再平均。
　　MA1=MA（CLOSE，5）；
　　MA2=MA（CLOSE，10）；
　　(MA1+MA2)/2;
　　
　　3、N日均線向上?。ū绢}反映均線波浪式延伸過程中某階段的形態(tài)。）
　　AA:=MA(C,N);
　　BB:=REF(AA,1);
　　AA>BB
　
　　均線向下呢？　AA< BB 就可以了。
　　N日均線走平怎么表述？AA=BB
　　
　　4、均線由下跌狀態(tài)剛剛轉(zhuǎn)為上升
　　AA:=MA(C,N);
COUNT(AA<REF(AA,1),6)=5 //用來確認前5日處于下跌狀態(tài)
AND AA>REF(AA,5)；
　　
　　5、年線拐頭向上
　　A250:=MA(C,250);
　　REF(A250,1)<REF(A250,2) AND A250>REF(A250,1);
　　
　　6、兩條均線交叉
　　股軟中專門設(shè)定了一條函數(shù)來描述兩條線交叉：CROSS（X，Y） ，此函數(shù)通用。
　　假如兩條均線一條名叫X，另外一條叫Y 　且（X＜Y）
　　CROSS（X，Y）表示X向上穿過了Y 　通稱：金叉
　　CROSS（Y，X）表示Y向上穿過了X 　通稱：死叉
　　特別提示：交叉有兩種，一種是向上交叉，另一種是向下交叉。如果要求向上交叉時，X線必須比前一天高，所以需要加上　X>REF(X,1) 。完整的表達式為：CROSS（X，Y）AND　 X>REF(X,1)
　　加餐：
　　上述交叉是不限制周期的，有時我們會感到交叉特別頻繁，如何取得他們較長時間交叉一次的數(shù)據(jù)呢，系統(tǒng)提供了另一個函數(shù)： LONGCROSS(X,Y,N) 兩條線維持N周期后交叉。如果N等于15，則X　Y兩條線超過15天后交叉有效，否則不輸出。
　　
　　7、多次金叉（以常見的MACD指標為例）
　?。?）二次金叉
　　(COUNT(CROSS(DIF,DEA),20)=2 AND CROSS(DIF,DEA);
　?。?）二次死叉
　　COUNT(CROSS(DEA,DIF),20)=2 AND CROSS(DEA,DIF);
　　（3）0軸上二次金叉
　　COUNT(CROSS(DIF,DEA) AND DEA>0,20)=2 AND CROSS(DIF,DEA) AND
　　DEA>0;
　?。?）0軸上三次金叉
　　COUNT(CROSS(DIF,DEA) AND DEA>0,20)=3 AND CROSS(DIF,DEA) AND
　　DEA>0;
　　
　　8、三線金叉
　　A5:=MA(C,5);
　　A10:=MA(C,10);
　　A30:=MA(C,30);
　　AA:=CROSS(A5,A10);
　　BB:=CROSS(A5,A30);
　　CC:=CROSS(A10,A30);
　　COUNT(AA,3)=1 AND COUNT(BB,3)=1 AND COUNT(CC,3)=1;
　　
　　9、三線同時金叉
　　A5:=MA(C,5);
　　A10:=MA(C,10);
　　A20:=MA(C,20);
　　AA:=CROSS(C,A5);
　　BB:=CROSS(C,A10);
　　CC:=CROSS(C,A20);
　　AA AND BB AND CC;
　　
　　10、均線多頭排列
　　A1:=MA(C,N1);
　　A2:=MA(C,N2);
　　A3:=MA(C,N3);
　　A4:=MA(C,N4);
　　A1>A2 AND A2>A3 AND A3>A4;
　　
　　11、均線空頭排列3天以上
　　A1:=MA(C,N1);
　　A2:=MA(C,N2);
　　A3:=MA(C,N3);
　　A4:=MA(C,N4);
　　COUNT(A1< A2 AND A2< A3 AND A3< A4,3)>=3;

　　12、向前N日至M日出現(xiàn)過均線死叉（P1< P2）
　　AA:=MA(C,P1);
　　BB:=MA(C,P2);
　　CC:=REF(CROSS(BB,AA),N);
　　COUNT(CC,M);
　
　　13、均線粘合
　　MA1:=MA(C,5);
　　MA2:=MA(C10);
　　MA3:=MA(C,20);
　　P1:=ABS(MA1-MA2)+ABS(MA2-MA3);
　　P1/C<1/100 AND MA1>REF(MA1,1) AND MA2>REF(MA2,1);　

　　14、均線粘合（另種表達式）
　　MA1:=MA(C,5);
　　MA2:=MA(C,10);
　　MA3:=MA(C,30);
　　A:=MAX(MAX(MA1,MA2),MA3);
　　B:=MIN(MIN(MA1,MA2),MA3);
　　COUNT(ABS(A-B)/B<0.01,3)=3;表示已粘合3天（含3天）以上

　　15、多條均線粘合　　如5、10、20、30、120、250日移動平均線粘合
　　aa:=(ma(c,5)+ma(c,10)+ma(c,20)+ma(c,30)+ma(c,120)+ma(c,250))/6;
　　up:=aa*n/100+aa;
　　down:=aa-aa*n/100;
　　count(BETWEEN(ma(c,5),up,down) and BETWEEN(ma(c,10),up,down) and BETWEEN(ma(c,20),up,down) and BETWEEN(ma(c,30),up,down)and BETWEEN(ma(c,120),up,down) and BETWEEN(ma(c,250),up,down),m)=m;
n（2，1，500） m（10，1，100） 調(diào)整參數(shù)n為粘合程度，n值越小粘合的程度越高，即均線距離越近；m為粘合周期。